/*
 *
 *  -----------------------------------------------------------------
 *  Execution of this macro requires a license for uni-XEDIT Extended
 *  for each concurrent user of the macro.
 *  -----------------------------------------------------------------
 *
 *  invert - sway the display between currently displayed lines
 *           and currently excluded lines
 *
 *  Syntax:  invert
 *
 *
 *
 *  Modification History:
 *
 *  -- --- --     Macro originally contributed by Dan Hofferth, Allison
 *                  Engine Company
 *  09 Feb 96 twg Standard TWG comments added
 *
 *
 */

/* Invert hidden and displayed lines.                          -IEDH1 */
 
If Arg(1) ^= '' Then Do
   'COMMAND MSG Type "INVERT" to invert hidden and displayed lines.'
   Exit
   End
 
'COMMAND EXTRACT /DISPLAY/STAY/SIZE/LINE/MSGMODE'
 
If ( display.1 = 0 & display.2 = 0 ) Then Do
   'COMMAND SET DISPLAY 1 1'
   Exit
   End

If ( display.1 = 0 & display.2 = 1 ) Then Do
   'COMMAND SET STAY ON'
   'COMMAND SET DISPLAY 0 *'
   'COMMAND SET SELECT 0 :0'
   'COMMAND SET SELECT 0 *'
   'COMMAND SET DISPLAY 1 1'
   'COMMAND SET STAY 'stay.1
   Exit
   End
 
If ^( display.1 = 1 & display.2 = 1 ) Then Do
   'COMMAND EMSG ** Display settings not recognized.  INVERT cancelled. **'
   Exit 1
   End
 
'COMMAND SET STAY ON'
'COMMAND SET DISPLAY 0 *'
'COMMAND :1'

'COMMAND SET MSGMODE OFF'
Do size.1
   'COMMAND EXTRACT /SELECT'
   If select.1 = 0 Then 'COMMAND SET SELECT 1'
   Else                 'COMMAND SET SELECT 0'
   'COMMAND NEXT'
   End
'COMMAND SET MSGMODE 'msgmode.1

'COMMAND :'line.1
'COMMAND SET DISPLAY 1 1'
'COMMAND SET STAY 'stay.1
 
Exit